Basic emulation space$() macro.

[hutch--]

I have been porting some basic code of late and this one helped to make some of it easier and faster.

Code Select Expand


; ¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤

    charfill PROTO :DWORD,:DWORD,:DWORD

; ¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤

; EXAMPLE

    local spc$  :DWORD          ; DWORD handle for string
    .....
    mov spc$, space$(1024)      ; allocate a space filled string
    .....
    free$ spc$                  ; deallocate it when finished

; ¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤

    space$ MACRO bcnt
      push esi
      mov esi, alloc$(bcnt)
      invoke charfill,esi,bcnt,32
      mov eax, esi
      pop esi
      EXITM <eax>   ;; dealloc with free$
    ENDM

; ¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤

OPTION PROLOGUE:NONE
OPTION EPILOGUE:NONE

    align 16

charfill proc buff:DWORD,bcnt:DWORD,char:DWORD

    mov ecx, [esp+4]        ; data address
    mov edx, [esp+8]        ; fill count
    mov eax, [esp+12]       ; fill character
    sub ecx, 1

  @@:
    add ecx, 1
    mov [ecx], al
    sub edx, 1
    jnz @B

    ret 12

charfill endp

OPTION PROLOGUE:PrologueDef
OPTION EPILOGUE:EpilogueDef

; ¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤


[NightWare]

hi,
it should be a bit faster if you accept 07FFFFFFFh as max value for fill count :

Code Select Expand

    mov ecx, [esp+4]        ; data address
    mov edx, [esp+8]        ; fill count
    mov eax, [esp+12]       ; fill character
    add ecx,edx
    neg edx
  @@:
    mov [edx+ecx], al
    add edx, 1
    jnz @B