For Loop To Assembly

[jwill22]

Trying to convert this:

Code Select Expand

int sum = 0;

for(int i = 0; i <=25;i++)
{
sum = (i * 2) + sum;
}

cout << sum <<endl;


to assembly.

Here's What I got...the answer is 650 in c++ and my answer is 675. Can somebody tell me what I'm doing wrong or if I'm doing anything wrong. Thanks:D:D

Code Select Expand

INCLUDE Irvine32.inc

.data
sum DWORD 0
counter DWORD 0


.code
main PROC
mov ebx,0
mov ecx, 25

.while(counter <= 25)
mov eax,2
mov ebx,counter
mul ebx
add sum,eax
add ebx,sum
inc counter


.ENDW
mov eax,ebx
call WriteDec

[qWord]

look at:

Code Select Expand

add eax,ebx
...
mov eax,ebx
call WriteDec

here an variant without MUL:

Code Select Expand

xor ecx,ecx
xor ebx,ebx
.while SDWORD ptr ecx <= 25
lea ebx,[ecx*2+ebx]
lea ecx,[ecx+1]
.endw
;ebx = result

[dedndave]

Code Select Expand

        xor     eax,eax
        mov     ecx,26

loop00: mov     edx,ecx
        dec     edx
        shl     edx,1
        add     eax,edx
        loop    loop00

        call    WriteDec

[jwill22]

So what's the xor for?

[dedndave]

XOR EAX,EAX is the same as SUB EAX,EAX - it zero's the EAX register, but is smaller than MOV EAX,0
sometimes, you may want to preserve the flags, though
in that case

Code Select Expand

        push    0
        pop     eax

[qWord]

sometimes, you may want to preserve the flags, though
in that case

Code Select Expand

        push    0
        pop     eax

omg :-)

[jwill22]

So why was my answer not 650?

[qWord]

Code Select Expand


.while(counter <= 25)
mov eax,2
mov ebx,counter
mul ebx
add sum,eax
add ebx,sum   ; ebx = counter*2 + counter*2 + sum
inc counter


.ENDW
mov eax,ebx ; <--- this should be mov eax,sum
call WriteDec

[dedndave]

omg :-)

saves a byte   :P
although, MOV EAX,0 might be faster

[Shooter]

Code Select Expand

        xor     eax,eax
        mov     ecx,26

loop00: mov     edx,ecx
        dec     edx
        shl     edx,1
        add     eax,edx
        loop    loop00

        call    WriteDec

Dave,
Wouldn't the loop count down to ECX=0? Wouldn't that make it 27 iterations instead of 26?

[tenkey]

ECX is decremented at the loop instruction and the *result* is tested for zero.
That means the looped code is NOT executed when ECX is zero.
Thus it's 26-count.

[clive]

Code Select Expand

        xor     eax,eax
        mov     ecx,26

loop00: lea edx,[ecx*2 - 2]
        add     eax,edx
        loop    loop00

        call    WriteDec
or

Code Select Expand

        xor     eax,eax
        mov     ecx,26

loop00: lea eax,[eax + ecx*2 - 2]
        dec     ecx
        jnz     loop00

        call    WriteDec
or

Code Select Expand

        xor     eax,eax
        mov     ecx,26

loop00: dec ecx
lea eax,[eax + ecx*2]
        jnz     loop00

        call    WriteDec

And of course the final iteration is pointless as it adds ZERO

[MichaelW]

Not very compact, but at least it's clear how it works:

Code Select Expand


.data
    sum dd 0
.code
FOR i,<0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25>
    mov eax, i
    shl eax, 1
    add sum, eax
ENDM


[dedndave]

here is an even simpler version - small code, too   :P

Code Select Expand

        push    25
        xor     eax,eax
        pop     ecx

loop00: add     eax,ecx
        add     eax,ecx
        loop    loop00

        call    WriteDec

[lingo]

"here is an even simpler version - small code, too"

It is smaller: :lol

Code Select Expand


mov  eax, 28Ah
call WriteDec