i wonder to create a file and then put all my result to the file, i can create a file but i have no idea how to write my result to the created file..i try to use int21h function 40h but i doesnt work, can plz any1 here teach me to do that?
.data
outfile db "result.txt"
stat db "hello world",0
.code
;create the output file
mov ax,716ch
mov bx,1
mov cx,0
mov dx,12h
mov si,offset outfile
int 21h
jc quit
mov outhandle,ax
;write buffer to new file
mov ah,40h
mov bx,outhandle
mov cx,bytesread
mov dx,offset stat
int 21h
jc quit
;close file
mov ah,3eh
mov bx,outhandle
int 21h
Here's how to save to a file:-
SAVE: DB 'C:\FOLDER\FILE NAME',0
DATA DB ?
HANDLE DW ?
MOV DX,SAVE ;File path & name
MOV AH,03C ;Function get handle
XOR CX,CX ;And open file
INT 021 ;For writing
JC ERROR ;If error goto error handling
XCHG AX,BX ;Ready to write
MOV HANDLE,BX ;Store handle
MOV AH,040 ;Function write to file
LEA DX,DATA ;Point at data entry point
MOV CX,? ; bytes in file
INT 021 ;Write to file
CMP AX,? ;Check total bytes written
JNE Error ;Go to error handling if not correct
MOV BX,HANDLE ;Get file handle
MOV AH,03E ;Function close file
INT 021 ;Close file
RET
ERROR ;Handle error here
Neil,
i scare i do not understand about your codes, i do not know how is the data put..
for example,
output db "Hello world",0
if i want to save this "Hello world" to my created file, then where should i move the output to?
Thanks for your reply... :bg
Put the data inside a file & name it anything you like, then put it into the path :-
SAVE: DB 'C:\FOLDER\YOUR FILE HERE',0
Neil,
can you please explain a little bit more ? actually what is the (data db ?) use for ? is it i put the thing i wan to display at data such as "hello world" ?
and also the (handle dw ?) ?
and then in your code written (mov cx,? ;bytes in file) and (cmp ax,? ;check total bytes written) what is the use of these two lines?
fname db 'result.txt',0 ;filename, zero-terminated
string db 'Hello World' ;what to write to the file
count equ $-string ;the length of the string above
;create output file
mov ah,3ch ;DOS function "create file"
mov cx,20h ;attributes - bit 5 is the "archive" attribute
lea dx,fname ;DS:DX has the filename address
int 21h ;ask DOS nicely...
jc error ;and abort if there's an error
mov bx,ax ;keep the file handle in BX, since DOS usually
;saves BX, and for many DOS calls BX=handle
;write the string to the file
mov ah,40h ;DOS function "write handle"
;here we would load the handle into BX, but it's already there.
mov cx,count ;how many bytes to write
lea dx,string ;DS:DX has the buffer address
int 21h ;ask DOS
jc error ;
cmp ax,cx ;on return AX=bytes actually written
jb error ;so if less were written then there's a problem
;close the file and we're done
mov ah,3eh ;DOS function "close handle"
;again, here we would load the handle into BX, but it's already there.
int 21h
thx sinsi, i can get what your code wrote there.. :bg
now i face another problem, at first i had create a file and managed to write a data "hello world" to the file, but then when i try to write more data to the same file, it comes out with problem, can anyone help me check where is my mistake ? and when i declare 2 data in a identifier just like my code below, the result just show the first line which is "hello world" and "welcome to my world" is just dissappear, why?
.model small
.stack
.data
cr = 0dh
lf = 0ah
fn db "result.txt",0
buf db "hello world",cr,lf
db "welcome to my world",0
buf1 db "hello world 2",0
.code
.startup
mov ah, 3Ch ; Create File with Handle
mov cx, 0 ; attributes = normal
mov dx, OFFSET fn ; DS:DX -> filename
int 21h
mov bx, ax ; store handle in BX
mov ah, 40h ; Write File or Device
; handle in BX
mov cx, SIZEOF buf ; bytes to write
sub cx, 1 ; eliminate trailing null
mov dx, OFFSET buf ; DS:DX -> buffer
int 21h
mov ah, 3Eh ; Close File with Handle
; handle in BX
int 21h
mov ah,3dh
mov al,2
mov dx,offset buf1
;mov si,OFFSET buf1
int 21h
mov bx,ax
mov cx, SIZEOF buf1 ; bytes to write
sub cx, 1 ; eliminate trailing null
mov dx, OFFSET buf1 ; DS:DX -> buffer
int 21h
mov ah, 3Eh ; Close File with Handle
; handle in BX
int 21h
.exit
end
if i use int 21h 716ch instead of int 21h 3dh ? what is the difference?
Added code tags to make the code easier to read and copy.
Hello,
You create a file with the name in 'fn'.
You write to it the contents of 'buf'.
You close the file.
You try to open a file with the name in 'buf1'. That probably
does not work.
You do a DOS INT with your file handle or error number in AX.
You probably don't get any further. As you probably called
function zero.
HTH,
Steve N.
Thanks Steve,
i did a stupid mistake..=.=
but after i correct it, it can assemble but when i run it, an error stating { the NTVDM CPU has encountered an illegal instruction. CS:d1e3 IP:d1e3 OP:ff ff ff ff ff }
what is it about?
Quotewhat is it about?
Well, what happens if you use DEBUG.EXE to look at your
program? Use DEBUG's P command to step through your
program and see what happens. Use the U command to
look at your program.
Good luck,
Steve N.
emm, Steve sorry to tell that, i am totally new to masm, so i have no idea how to use debug.exe, p command all that, where can i find it and how to use it?
For those looking to learn 16-bit DOS coding, this might be the best series of tutorials out there:
http://www.btinternet.com/~btketman/tutpage.html
Includes an interactive assembly interpreter.
boon,
For each open file, DOS maintains a file pointer that stores the current position in the file. When a file is created or opened DOS sets the file pointer to 0, which is the position of the first byte in the file. The Write File or Device function starts writing to the file at the location specified by the file pointer, and then updates the file pointer so it points to the first byte after the last byte written. So to add more data to the end of the file you would simply call the Write File or Device function again, with DS:DX pointing to the new data, and the length of the new data in CX.
Also, you can control the position of the file pointer with Function 42h, Move File Pointer. This could be used to overwrite data at any position in the file, or truncate the file at any length.
.model small
.stack
.data
cr = 0dh
lf = 0ah
fn db "result.txt",0 ; filename needs null terminator
buf db "hello world",cr,lf,"welcome to my world",cr,lf
buf1 db "hello world 2",cr,lf
.code
.startup
mov ah, 3Ch ; Create File with Handle
mov cx, 0 ; attributes = normal
mov dx, OFFSET fn ; DS:DX -> filename
int 21h
mov bx, ax ; store handle in BX
mov ah, 40h ; Write File or Device
; handle in BX
mov cx, SIZEOF buf ; bytes to write
;sub cx, 1 ; eliminate trailing null
mov dx, OFFSET buf ; DS:DX -> buffer
int 21h
;mov ah, 3Eh ; Close File with Handle
; handle in BX
;int 21h
;mov ah,3dh
;mov al,2
;mov dx,offset buf1
;mov si,OFFSET buf1
;int 21h
;mov bx,ax
mov ah, 40h ; Write File or Device
; handle in BX
mov cx, SIZEOF buf1 ; bytes to write
;sub cx, 1 ; eliminate trailing null
mov dx, OFFSET buf1 ; DS:DX -> buffer
int 21h
mov ah, 3Eh ; Close File with Handle
; handle in BX
int 21h
.exit
end
MichaelW, really thanks alot, you lead me have clearer image about the input and output file...and thanks to Mark Jones for introducing the websites to me..Great to meet you guys here... :bg
another problem...when i try to pass a value i calculated to an uninitialize identifier, n write to the file i have created, the result just show ? in the file, why is this happen?
buf2 db ?
one db 1
two db 2
...
mov ax,one
add ax,two
mov buf2,ax
anyone please help me solve my problem? i had try many methods but all seem not working, it keep print the "?" but not the value i calculated..
You are defining your data as bytes (db), but accessing them as words (ax).
If you want to write "3" to your file you have to convert it (hint: look at the masm32 functions).
Quote from: boon on September 16, 2008, 04:45:04 PM
emm, Steve sorry to tell that, i am totally new to masm, so i have no idea how to use debug.exe, p command all that, where can i find it and how to use it?
On this Windows XP system, I found;
Directory of C:\WINDOWS\system32
08/29/2002 07:00 AM 20,634 debug.exe
1 File(s) 20,634 bytes
There are tutorials out on the web. Or you could go to
Google Groups and search comp.lang.asm.x86 and
alt.lang.asm to see if there is a preferred tutorial. Running
debug, and typing a question mark gives a command summary.
C:\>debug
-?
assemble A [address]
compare C range address
dump D [range]
enter E address
fill F range list
go G [=address] [addresses]
hex H value1 value2
input I port
load L [address] [drive] [firstsector] [number]
move M range address
name N [pathname] [arglist]
output O port byte
proceed P [=address] [number]
quit Q
register R [register]
search S range list
trace T [=address] [value]
unassemble U [range]
write W [address] [drive] [firstsector] [number]
allocate expanded memory XA
[#pages]
deallocate expanded memory XD [handle]
map expanded memory pages XM [Lpage] [Ppage] [handle]
display expanded memory status XS
-q
C:\>
[/tt]
The Proceed command steps through the program one
line at a time.
Basically, you produce a listing of your code so you can
see what opcodes your code produces, and the address
of each opcode. Then run debug with your program's
name on the command line. You can then step through
the program and see what happens to the registers.
An example with code I posted in another thread. I
start the debugger.
E:\MASM\WORK>debug testtext.com
- I can use the U command to look at the code.
152A:0100 8CC8 MOV AX,CS
152A:0102 8ED8 MOV DS,AX
152A:0104 B80300 MOV AX,0003
152A:0107 CD10 INT 10
152A:0109 B800B8 MOV AX,B800
152A:010C 8EC0 MOV ES,AX{snip}
And then step through using the P command.
-p
AX=152A BX=0000 CX=0076 DX=0000 SP=FFFE BP=0000 SI=0000 DI=0000
DS=152A ES=152A SS=152A CS=152A IP=0102 NV UP EI PL NZ NA PO NC
152A:0102 8ED8 MOV DS,AX
-p
AX=152A BX=0000 CX=0076 DX=0000 SP=FFFE BP=0000 SI=0000 DI=0000
DS=152A ES=152A SS=152A CS=152A IP=0104 NV UP EI PL NZ NA PO NC
152A:0104 B80300 MOV AX,0003
-p
AX=0003 BX=0000 CX=0076 DX=0000 SP=FFFE BP=0000 SI=0000 DI=0000
DS=152A ES=152A SS=152A CS=152A IP=0107 NV UP EI PL NZ NA PO NC
152A:0107 CD10 INT 10
- The first line was MOV AX,CS so the first P executes that and
you can see 152A in AX. Then DS is updated, though to the same
value it holds. Then AX is loaded with 3 in preparation for the INT.
Easy as rhubarb pie? The simpler commands are fairly easy to use.
Try and locate a tutorial before doing much more than U (unassemble),
P (proceed), D (dump), G (go, which starts running your program),
and of course Q (quit).
HTH,
Steve N.
boon,
As sinsi pointed out, the three instructions should all return:
error A2070: invalid instruction operands
When you try to assemble them because the operands are different sizes (AX is a word, and one, two, and buf2 are defined as bytes).
If you are trying to add the values 1 and 2 to get the value 3, and then write the digit "3" to the file, you will need code to convert a value to a decimal (base 10) or hexadecimal (base 16) digit. To convert the values from 0 to 9 to a decimal digit, you can simply add the ASCII code for 0 (= 48) to the value. For example:
0+48=48, the ASCII code for the digit "0"
1+48=49, the ASCII code for the digit "1"
. . .
9+48=57, the ASCII code for the digit "9"
For values > 9, you will need more complex code to convert the value to a string. This has been discussed many times, try searching the forum for the word decimal. If you use the Advanced search and narrow the search to the 16-bit DOS programming board, you should find some simple examples.
i had define word to all the three identifiers and it works, thanks guys...but when come to convert value to string i really don't have any idea about it..i had seen some examples on the forum but with my kindergarden level of assembly language, i can't understant how is it running..somemore i need to convert floating point to string so that i can write it to my file and it is more complicated than convert decimal to string...God help...getting crazy with assembly language...
QuoteThe Proceed command steps through the program one line at a time.
Just a nitpick, you should use Trace to step through one
instruction at a time.
If you have "call ...." then Proceed will not trace into that subroutine but call it without tracing.
Good for when your code has "int 21h" - you don't want to trace through that.
boon, converting hex into a string is hard enough, floating-point is harder still.
You're in the 16-bit (DOS) subforum, is there a reason you are sticking to DOS? Win32 is a hell of a lot easier
and there's a lot of code here on the board and in the masm32 package.
actually i am taking microprocessor subject now and at first my lecturer ask us to use 16-bit to write a program calculating quadratic equation, he said 16-bits is the basic so start learning from it..and now i am improving my program so that i can save the previous result, but seems there are lots problems...in addition, when i want borrow referrence books from library, every books are teaching 16-bits and none of the books are teaching 32-bit programming..that's why i have to stick with 16-bit dos programming...
Hi sinsi,
You are correct. However since the posted code had INT's
and no CALL's, I thought to keep it simple. Maybe too simple?
And of course the Dump command for looking at data is useful,
but did not seen relevant then. But if he is having trouble
saving results?
Regards,
Steve