.if eax==IDC_BTN1
invoke InternetOpen,0,0,0,0,0
mov hInet,eax
invoke GetDlgItemText,hWnd,1001,addr Url,400
invoke InternetOpenUrl,hInet,eax,0,0,0,0
invoke GetDlgItemText,hWnd,1002,addr LocalFile,256
invoke CreateFile,addr LocalFile,GENERIC_WRITE,FILE_SHARE_READ,NULL,OPEN_ALWAYS,FILE_ATTRIBUTE_NORMAL,NULL
mov hFile,eax
invoke InternetReadFile,Url,BUFFER,2000h,rwURL
invoke WriteFile,[hFile],BUFFER,[rwURL],rwFile,0
invoke CloseHandle,[hFile]
invoke InternetCloseHandle,[hInet]
.endif
(I tryed to create simple downloader.)
Why it doesn't work ? This program closes after CreateFile (the file has zero size :( ); :dazzled:
I see nothing obvious, but try replacing OPEN_ALWAYS, in the call to createfile, with CREATE_ALWAYS (or CREATE_NEW)
Hi,
test these adjustments..
.if eax==IDC_BTN1
invoke InternetOpen,0,0,0,0,0
mov hInet,eax
invoke GetDlgItemText,hWnd,1001,addr Url,400
invoke InternetOpenUrl,hInet,eax,0,0,0,0 ;<-- The return value of "GetDlgItemText" is the number of tchar copied. Replace eax by "addr Url"
; add this:
mov hUrl,eax ; hUrl == DWORD
invoke GetDlgItemText,hWnd,1002,addr LocalFile,256
invoke CreateFile,addr LocalFile,GENERIC_WRITE,FILE_SHARE_READ,NULL,OPEN_ALWAYS,FILE_ATTRIBUTE_NORMAL,NULL
mov hFile,eax
invoke InternetReadFile,Url,BUFFER,2000h,rwURL ; replace Url by "hUrl", and replace rwURL by "addr rwURL"
invoke WriteFile,[hFile],BUFFER,[rwURL],rwFile,0
invoke CloseHandle,[hFile]
;add this:
invoke InternetCloseHandle,hUrl
invoke InternetCloseHandle,[hInet]
.endif
Note: Like said it Tedd, it is preferable to replace "OPEN_ALWAYS" by "CREATE_ALWAYS"...
THX, but it crashes again :(
hInstance dd ?
CommandLine dd ?
hWnd dd ?
Url db ?
LocalFile db ?
hFile dd ?
hInet dd ?
hUrl dd ?
rwURL dd ?
rwFile dd ?
BUFFER dd 2000h
may be i have some wrong definitions ? ::)
As Faiseur pointed out, this line:
invoke InternetOpenUrl,hInet,eax,0,0,0,0
is wrong. Change it to:
invoke InternetOpenUrl, hInet, ADDR Url, 0, 0, 0, 0
You were effectively passing garbage as your url. And as he also pointed out, don't forget to change the InternetReadFile line, you need to use pointers.
Hi,
this is my procedure, with checks...return 1 if success or 0 if errors.
Syntax of call:
invoke GetWinInetFile, addr Url, addr LocalFile
Correct your datas:
Url db 256 dup(?)
LocalFile db 256 dup(?)
GetWinInetFile PROTO :DWORD,:DWORD
.code
; Success == 1, 0 == error
GetWinInetFile PROC fUrl,fSav:DWORD
LOCAL hUrl,fHand,bwrite,szBuffer,hSession: DWORD
LOCAL Buffer[1024]: BYTE
mov hSession, FUNC (InternetOpen,chr$('toto'),INTERNET_OPEN_TYPE_PRECONFIG,NULL,NULL,NULL)
.if hSession != 0
mov hUrl,FUNC (InternetOpenUrl,hSession,fUrl,NULL,NULL,NULL,NULL)
.if hUrl != 0
mov fHand, FUNC (CreateFile,fSav,GENERIC_READ or GENERIC_WRITE,FILE_SHARE_READ,0,CREATE_ALWAYS,FILE_ATTRIBUTE_NORMAL,0)
.if fHand != INVALID_HANDLE_VALUE
inc szBuffer
.WHILE szBuffer != 0
invoke InternetReadFile,hUrl,addr Buffer,sizeof Buffer,addr szBuffer
invoke WriteFile,fHand,addr Buffer,szBuffer,ADDR bwrite,NULL
.ENDW
invoke CloseHandle,fHand
invoke InternetCloseHandle,hUrl
invoke InternetCloseHandle,hSession
.endif
.endif
.endif
ret
GetWinInetFile ENDP
I don't know why it doesn't work ::) ; please have a look... It's project for RadASM.
[attachment deleted by admin]
Ok, your project work if you take the values "Url" and "LocalFile" before using the procedure GetWinInetFile... And no put Null value in the last parameter of GetDlgItemText. This specifies the maximum length of the string to be copied to the buffer.
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/winui/winui/windowsuserinterface/windowing/dialogboxes/dialogboxreference/dialogboxfunctions/getdlgitemtext.asp
invoke GetDlgItemText,hWnd,1001,addr LocalFile,sizeof LocalFile
invoke GetDlgItemText,hWnd,1002,addr Url,sizeof Url
invoke GetWinInetFile,addr Url,addr LocalFile
You must recover the parameters necessary to the procedure BEFORE calling it. See GetWinInetFile as if it is an API function. With API you not recover the parameters in its function but, of course, before using it. It is the same thing here. Always see a procedure like something of separate with your main program. :wink
Note: i have added macros (include \masm32\macros\macros.asm) Switch, Case and Func. That makes the code readable for me. Sorry if that does not help you.
[attachment deleted by admin]
Nice job Fraiseur, works perfectly in a WinXP console box.
One question, what is 'toto' for in InternetOpen,chr$('toto')? Thanks. :)
One question, what is 'toto' for in InternetOpen,chr$('toto')? Thanks. :)
Hé hé :wink
In the msdn, this parameter is the "lpszAgent":
" [in] Pointer to a null-terminated string that specifies the name of the application or entity calling the WinINet functions. This name is used as the user agent in the HTTP protocol."
That seems useless for a simple download without ftp. But to avoid a possible error I place a name by defect.
thanks Faiseur, but it doesn't download files and i don't know why ::) :
For Example i tryed to use "http://www.freshdevices.com/files/frui.exe" as Url
and "D:\1.exe" as LocalFile executing : fn MessageBox,0, "Error"," ",0
How to make it download files :dazzled:
Hi,
i have tested your example, function fine.
(http://uk.trojanfrance.com/1.jpg)
Downloaded 845ko.
Perhaps check that your FW accept your program.
THANK YOU It works! :cheekygreen:
How to cut Url string to get file name :eek?
Hi,
see this thread:
http://www.masmforum.com/simple/index.php?topic=896.msg6415#msg6415
I don't understand this :( Is there any API Function for getting filename from url? ::)
Is it possible to connect size of the file with the progress on the ProgressBar?
(How to get current file size in percents?)
May be here:
.WHILE szBuffer != 0
invoke InternetReadFile,hUrl,addr Buffer,sizeof Buffer,addr szBuffer
invoke WriteFile,fHand,addr Buffer,szBuffer,ADDR bwrite,NULL
.ENDW
Quote from: KoDeR on June 04, 2005, 11:00:14 AM
I don't understand this :( Is there any API Function for getting filename from url? ::)
See:
InternetCrackUrl :wink (in wininet.inc)
typedef struct {
DWORD dwStructSize;
LPTSTR lpszScheme;
DWORD dwSchemeLength;
INTERNET_SCHEME nScheme;
LPTSTR lpszHostName;
DWORD dwHostNameLength;
INTERNET_PORT nPort;
LPTSTR lpszUserName;
DWORD dwUserNameLength;
LPTSTR lpszPassword;
DWORD dwPasswordLength;
LPTSTR lpszUrlPath;
DWORD dwUrlPathLength;
LPTSTR lpszExtraInfo;
DWORD dwExtraInfoLength;
} URL_COMPONENTS,
*LPURL_COMPONENTS;
Members
dwStructSize
Size of this structure, in bytes.
lpszScheme
Pointer to a string that contains the scheme name.
dwSchemeLength
Size of the scheme name, in TCHARs.
nScheme
INTERNET_SCHEME value that indicates the Internet protocol scheme.
lpszHostName
Pointer to a string that contains the host name.
dwHostNameLength
Size of the host name, in TCHARs.
nPort
Converted port number.
lpszUserName
Pointer to a string value that contains the user name.
dwUserNameLength
Size of the user name, in TCHARs.
lpszPassword
Pointer to a string that contains the password.
dwPasswordLength
Size of the password, in TCHARs.
lpszUrlPath
Pointer to a string that contains the URL path.
dwUrlPathLength
Size of the URL path, in TCHARs.
lpszExtraInfo
Pointer to a string that contains the extra information (for example, ?something or #something).
dwExtraInfoLength
Size of the extra information, in TCHARs.
Where is Filename ?
It will be the last component after in the string pointed to by lpszUrlPath
So, using dwUrlPathLength to start at the end of that string.. check each character, moving backwards, until you get to the '/' and then move forward one - and that's the start of the filename :wink. You'll probably also have to check just in case there is no '/' so you don't keep scanning past the start of the string (in which case start of the filename is the start of the string.)
So, using dwUrlPathLength to start at the end of that string.. check each character, moving backwards, until you get to the '/' and then move forward one - and that's the start of the filename wink. You'll probably also have to check just in case there is no '/' so you don't keep scanning past the start of the string (in which case start of the filename is the start of the string.)
I've guessed that :8)
But i don't know how to reach character with number NUM in the string STRING :'(
In Delphi it looks so :
while Edit1.Text<>'/' do i:=i-1;
And is it posible to work with Edits and Buttons like that Edit1.Text and etc.
(Warning: vomitted code - may not work without a bit of tweaking)
.data?
url_parts db URL_COMPONENTS <?>
.
.code
.
.
mov edi,[url_parts].lpszUrlPath
mov ecx,[url_parts].dwUrlPathLength
@again:
mov al,[edi+ecx]
cmp al,'/'
je @found_it
dec ecx
jmp @again
@found_it:
inc ecx ;move forward one character
lea eax,[edi+ecx]
;eax points to the filename string
.
.
As for Edit1.Text and such things - these are shortcuts that vb provides for you. You have to do it yourself in asm :P
To get the contents of an edit box, you have to send it a WM_GETTEXT message (and provide some memory for it to put the contents.)
I was tinkering with a similar idea and came up with this:
.data ; initialized data
Url db "http://heliosstudios.net/temp/winasm.png",0
.data? ; runtime (uninitialized) data
filename dd ?
.code
print chr$("URL: ")
print addr Url
print chr$(13,10)
mov edx, offset Url ; load offset of Url
@@:
mov al, byte ptr [edx] ; get a byte into al
cmp al, 00 ; end of url?
je @F
inc edx ; search forward
jmp @B
@@: ; now edx points at end of Url
dec edx ; backup one
mov al, byte ptr [edx] ; load it
cmp al, "/" ; is the last char a "/"?
jnz @F ; if not, leave it alone
mov byte ptr [edx], 00 ; if so, overwrite it
@@: ; we are now at the end of the filename
dec edx ; search backwards one
mov al, byte ptr [edx] ; load byte
cmp al, "/"
jnz @B ; keep looping until the next / is found
inc edx ; move forward one
mov filename, edx ; store pointer as filename
print chr$("Filename: ")
print dword ptr filename
Yeah, that should work too :wink and without InternetCrackUrl!! :U
KoDeR: forget about using InternetCrackUrl - if you only want the filename, then it's less work to extract it yourself. Just get the string length and then search backwards :toothy
I'm afraid I suggested that function without looking at exactly what it did ::)
Instead of WinInet, you might try the simpler UrlMon.DLL:
include \MASM32\INCLUDE\Urlmon.inc
includelib \MASM32\lib\Urlmon.lib
UrlBuf db "www.google.com",0
AddLoc db "C:\mydownloadedstuff.dat",0
...
invoke URLDownloadToFile,0,ADDR UrlBuf,ADDR AddLoc,0,0